Queries (TXM)

ANNIS example queries can be found in the ANNIS portal.

Manuscript word division

• Find all cases of token agglutination in the manuscript:

[wd_div="\+"]{1,4} []

• Find all tokens split into multiple words in the manuscript (hint: set the concordance to display word_dipl rather than word):

[dipl=".*[_\|].*"]

Morphophonology

• Find all cases of et ‘and’ and ad ‘to’ written with a final dental before a vowel:

[lemma_dmf="et|à" & phon=".*[ðd]"] [phon="[aeiouyæɛɔAEIOUÆ].*"]

• Find all cases of ne ‘not’ before a vowel-initial verb:

[lemma_dmf="ne"] [phon="[aeiouyæɛɔAEIOUÆ].*" & pos_syn="VERcjg"]

• Find all prosodically enclitic pronouns:

[phon=".*[aeiouyæɛɔəAEIOUÆ]"] [pos="PRCper|PRCadv" & phon="[^aeiouyæɛɔəAEIOUÆ]+"] [phon="[^aeiouyæɛɔAEIOUÆ].*"]

• Find all prosodically enclitic pronouns which are not agglutinated with the host in the manuscript:

[phon=".*[aeiouyæɛɔəAEIOUÆ]" & wd_div!="\+"] [pos="PRCper|PRCadv" & phon="[^aeiouyæɛɔəAEIOUÆ]+"] [phon="[^aeiouyæɛɔAEIOUÆ].*"]

Morphology and morphosyntax

• Find all occurrences of verb forms descended from the Latin pluperfect indicative:

[morph="indpqp.*"]

• Find all verbs in the second-person singular:

[morph=".*2"]

• Find all nouns in the masculine nominative singular not ending in -s:

[pos_syn="NOMcom" & morph="smn" & word!=".*[szx]"]

• Find all forms of the verb raiembre ‘to redeem’ in both languages:

[lemma_dmf="raiembre"]

• Find all postverbal object pronouns:

[pos="VERcjg"] [pos="PRCper|PRCadv" & morph!=".*n"]{1,3}

Meter and versification

These queries use the word-level metrical annotation for TXM. See Annotation 4: Syllables and Meter.

• Find all lines of verse with [ɔ] at the rhyme

[phon=".*[^i]ɔi?[^aeiouyæɛɔUÆ]*" & metpos=".*r"] 

• Find cases of line-initial object pronouns, i.e. possible exceptions to the Tobler-Mussafia law:

[pos="PRCper|PRCadv" & metpos="01.*"] [pos="PRCper|PRCadv"]{0,3} [pos="VERcjg"]

• Find all paroxytones at the end of the line

[prosody=".po" & metpos=".*r"]

• Find all cases of epic caesura in decasyllables (Due to a bug in version 0.4 of the corpus not all instances are found; this will be corrected in a future release.)

[line_met="10.e." & metpos=".*c"]

• Find all octosyllables stressed on the fourth syllable

[line_met="08.*" & ((metpos=".*04.." & prosody=".ox") | (metpos=".*05.." & prosody=".po"))]